Простое демо с интерактивностью

This message was edited 1 time. Last update was at 17/10/2009 12:26:54

Сделал на основе урока "Импорт модели". Теперь в сцене присутствуют два объекта с именами "Door"(Дверь) и "Plate"(Табличка с названием улицы). На объекты навешиваются обработчики событий. Обрабатывается клик на объекте и показано как сделать, чтобы при навдении на объект курсор сменялся на руку.

package {

import alternativa.engine3d.controllers.CameraController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Mesh;
	import alternativa.engine3d.core.Object3D;
	import alternativa.engine3d.core.Scene3D;
	import alternativa.engine3d.display.View;
	import alternativa.engine3d.events.MouseEvent3D;
	import alternativa.engine3d.loaders.LoaderOBJ;
	import alternativa.engine3d.materials.TextureMaterialPrecision;
	import alternativa.types.Point3D;
	import alternativa.utils.FPS;
	import alternativa.utils.MeshUtils;
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	
	[SWF(backgroundColor="#000000", frameRate="100")]
	public class StrannikDemo extends Sprite {

private var scene:Scene3D;
		private var view:View;
		private var camera:Camera3D;
		private var cameraController:CameraController;
		private var loader:LoaderOBJ;

public function StrannikDemo() {
			addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		/**
		 * 
		 */
		public function init(e:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			startLoading();
			initScene();
			initListeners();

onResize(null);
		}
		
		/**
		 * Создание сцены и камеры.
		 */
		private function initScene():void {
			// Создание сцены
			scene = new Scene3D();
			scene.root = new Object3D();
			// Добавление камеры и области вывода
			camera = new Camera3D();
			camera.x = 200;
			camera.y = -200;
			camera.z = 100;
			scene.root.addChild(camera);
			view = new View();
			addChild(view);
			view.camera = camera;
			// Подключение контроллера камеры
			cameraController = new CameraController(stage);
			cameraController.camera = camera;
			cameraController.setDefaultBindings();
			cameraController.checkCollisions = true;
			cameraController.collisionRadius = 20;
			cameraController.controlsEnabled = true;
			cameraController.speed = 500;
			cameraController.lookAt(new Point3D(0, 0, 100));
			// Запуск счётчика fps
			FPS.init(stage);
		}
		
		/**
		 * 
		 */
		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}
		
		/**
		 * 
		 */
		private function onEnterFrame(e:Event):void {
			// Обработка пользовательского ввода 
			cameraController.processInput();
			// Расчёт сцены
			scene.calculate();
		}
		
		/**
		 * 
		 */
		private function initListeners():void {
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
		
		/**
		 * Загрузка модели в формате 3DS.
		 */
		private function startLoading():void {
			loader = new LoaderOBJ();
			loader.smooth = true;
			loader.precision = TextureMaterialPrecision.HIGH;
			
			// При экспорте из 3DS Max неправильно сохраняются объекты как группы.
			// Включаем флаг, чтобы объекты определялись правильно.
			loader.objectsAsGroups = true;
			
			loader.load("resource/house.obj");
			loader.addEventListener(Event.COMPLETE, onLoadingComplete);
		}
		
		/**
		 * 
		 */		
		private function onLoadingComplete(e:Event):void {
			for (var o:* in loader.content.children) {
				var object:Object3D = o;
				weldVerticesAndFaces(object);
				scene.root.addChild(object);
			}
			// Включаем посылку мышиных событий из сцены объектам
			view.interactive = true;
			// Вешаем слушателей мышинных событий на объекты
			var door:Object3D = scene.root.getChildByName("Door", true);
			door.addEventListener(MouseEvent3D.MOUSE_OVER, onObjectMouseOver);
			door.addEventListener(MouseEvent3D.MOUSE_OUT, onObjectMouseOut);
			door.addEventListener(MouseEvent3D.CLICK, onDoorClick);
			var plate:Object3D = scene.root.getChildByName("Plate", true);
			plate.addEventListener(MouseEvent3D.MOUSE_OVER, onObjectMouseOver);
			plate.addEventListener(MouseEvent3D.MOUSE_OUT, onObjectMouseOut);
			plate.addEventListener(MouseEvent3D.CLICK, onPlateClick);
		}
		
		private function onObjectMouseOver(e:MouseEvent3D):void {
			view.buttonMode = true;
		}

private function onObjectMouseOut(e:MouseEvent3D):void {
			view.buttonMode = false;
		}

private function onDoorClick(e:MouseEvent3D):void {
			showMessage("Вы кликнули на дверь");
		}
		
		private function onPlateClick(e:MouseEvent3D):void {
			showMessage("Вы кликнули на табличку");
		}
		
		private function showMessage(message:String):void {
			var mesWindow:Sprite = new Sprite();
			mesWindow.graphics.beginFill(0x0, 0.7);
			mesWindow.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			var mesText:TextField = new TextField();
			mesText.defaultTextFormat = new TextFormat(null, 16, 0xFFFFFF, true);
			mesText.autoSize = TextFieldAutoSize.LEFT;
			mesText.selectable = false;
			mesText.text = message;
			mesText.x = (mesWindow.width - mesText.width)/2 + mesWindow.x;
			mesText.y = (mesWindow.height - mesText.height)/2 + mesWindow.y;
			mesWindow.addChild(mesText);
			addChild(mesWindow);
			mesWindow.addEventListener(MouseEvent.CLICK, function(e:MouseEvent):void {removeChild(mesWindow);});
		}
		
		/**
		 * Объединение вершин и граней объекта.
		 */
		private function weldVerticesAndFaces(object:Object3D):void {
			if (object is Mesh) {
				MeshUtils.autoWeldVertices(Mesh(object), 0.01);
				MeshUtils.autoWeldFaces(Mesh(object), 0.01, 0.001);
			}
			// Запуск процедуры для детей объекта
			for (var key:* in object.children) {
				weldVerticesAndFaces(key);
			}
		}
	}
}

Теперь все дошло.
Огромное спасибо

Во! Понятно, спасибо! А то с мышинными событиями не получалось...