Orbital mode

Is there a way to get the orbital mode with the CameraController like you have on the Alternativa Player?

This message was edited 1 time. Last update was at 17/08/2008 11:47:00

The current version of camera controller doesn't support this mode, but there's possibility to get it. Just put a camera inside of another camera and translate the inner camera along negative direction of Z axis, then assign parent camera to a controller and the inner camera to a view. The controller will rotate the parent camera and the inner camera will orbiting around center of the outer one. I must admit, it is a bit weird way to make a camera orbit, but for now there's no other option (except writing your own controller of course). There's a good chance that in the next update of 5.0 version will be new controller with extended functionality including orbital mode.

This message was edited 2 times. Last update was at 07/11/2008 00:35:11

Cool trick. Works well

I created it into a class (OrbitCamera3D) for anyone interested in using it before the next lib update:

package {
	import flash.display.DisplayObject;
	import alternativa.engine3d.controllers.CameraController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.display.View;
	import alternativa.types.Point3D;
	public class OrbitCamera3D extends Camera3D {
		public var viewCamera:Camera3D;
		public var cameraController:CameraController;
		private var eventsSourceObject:DisplayObject;
		public function OrbitCamera3D( eventsSourceObject:DisplayObject, view:View, distance:Number = 500 ) {
			super();
			viewCamera = new Camera3D();
			addChild( viewCamera );
			this.distance = distance;
			view.camera = viewCamera;
			this.eventsSourceObject = eventsSourceObject;
		};
		public function set distance( value:Number ):void {
			viewCamera.z = -value;
		};
		public function get distance():Number {
			return viewCamera.z;
		};
		public function lookAt( point:Point3D = null ):void {
			x = point.x;
			y = point.y;
			z = point.z;
		};
		public function processInput():void {
			if( cameraController ) {
				cameraController.processInput();
			} else if( Camera3D(this).parent ) {
				buildController();
			};
		};
		public function set focalPointX( value:Number ):void { x = value; };
		public function set focalPointY( value:Number ):void { y = value; };
		public function set focalPointZ( value:Number ):void { z = value; };
		public function get focalPointX():Number { return x; };
		public function get focalPointY():Number { return y; };
		public function get focalPointZ():Number { return z; };
		private function buildController():void {
			cameraController = new CameraController( eventsSourceObject );
			cameraController.camera = this;
			cameraController.lookAt( new Point3D( 0, 0, 0 ) );
			cameraController.controlsEnabled = true;
		};
	};
};

Useage:

It's contains the CameraController, so call this before you call Scene3D.calculate() :

You can also change its focalPoint but calling lookAt or changing its focalPointX, focalPointX, focalPointZ.

Heres my example

-Joe

Have anyone encountered the mouse wheel issue ?
When ever you scroll the mouse wheel the orbit code is freezing [

]

Yes, I just noticed this too. It looks by default a MouseEvent.MOUSE_WHEEL or MouseEvent3D.MOUSE_WHEEL listener is set. I get this error:

Since I don't have access to the Alternativa3D library source, I think were going to need the help of Team Alternativa on this.

So... we need to remove default mouseWheel event, or even better, tie it to my OrbitCamera3D.distance property.

Just use WalkController, it hasn't mouse wheel support

Hats off [

] it worked [

]

This message was edited 2 times. Last update was at 26/11/2008 22:50:14

Yeah, that worked, but now the focalPointX, focalPointY, focalPointZ, and lookAt(), don't work... What am I missing here?? Here is the update with the WalkController update:

package {
	import flash.display.DisplayObject;
	import flash.events.MouseEvent;
	import alternativa.engine3d.controllers.WalkController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.display.View;
	import alternativa.types.Point3D;
	import alternativa.engine3d.core.Object3D;
	public class OrbitCamera3D extends Camera3D {
		public var viewCamera:Camera3D;
		public var controller:WalkController;
		public var onStartMoving:Function;
		public var onStopMoving:Function;
		public var onStartDragging:Function;
		public var onStopDragging:Function;
		private var eventsSourceObject:DisplayObject;
		public function OrbitCamera3D( eventsSourceObject:DisplayObject, view:View, distance:Number = 500 ) {
			super();
			viewCamera = new Camera3D();
			addChild( viewCamera );
			this.distance = distance;
			view.camera = viewCamera;
			this.eventsSourceObject = eventsSourceObject;
		};
		public function set distance( value:Number ):void {
			viewCamera.z = -value;
		};
		public function get distance():Number {
			return -viewCamera.z;
		};
		public function lookAt( point:Point3D = null ):void {
			controller.coords.x = point.x;
			controller.coords.y = point.y;
			controller.coords.z = point.z;
		};
		public function processInput():void {
			if( controller ) {
				controller.processInput();
			} else if( Camera3D(this).parent ) {
				buildController();
			};
		};
		public function set focalPointX( value:Number ):void { controller.coords.x = value; };
		public function set focalPointY( value:Number ):void { controller.coords.y = value; };
		public function set focalPointZ( value:Number ):void { controller.coords.z = value; };
		public function get focalPointX():Number { return controller.coords.x; };
		public function get focalPointY():Number { return controller.coords.y; };
		public function get focalPointZ():Number { return controller.coords.z; };
		private function buildController():void {
			controller = new WalkController( eventsSourceObject );
			controller.object = this;
			controller.unbindAll()
			controller.lookAt( new Point3D( 0, 0, 0 ) );
			controller.onStartMoving = function() {
				if( onStartMoving != null ) onStartMoving(); 
			};
			controller.onStopMoving = function() {
				if( onStopMoving != null ) onStopMoving(); 
			};
			eventsSourceObject.addEventListener( MouseEvent.MOUSE_DOWN, _onStartDragging );
			eventsSourceObject.addEventListener( MouseEvent.MOUSE_UP, _onStopDragging );
			addEventListener( MouseEvent.MOUSE_UP, _onStopDragging );
		};
		private function _onStartDragging( event:MouseEvent ):void {
			if( onStartDragging != null ) onStartDragging(); 
		};
		private function _onStopDragging( event:MouseEvent ):void {
			if( onStopDragging != null ) onStopDragging(); 
		};
		
		
	};
};

Walk controller overrides an object's coordinates now. You should use the "coords" property of a controller instance.

This message was edited 3 times. Last update was at 26/11/2008 22:55:14

I tried that, but it still doesn't render the new angle when changing the controller's coords? This is what I tried:

It didn't have a problem moving until I switched it to the WalkController to get rid of the mouseWheel error... Is the WalkController making it immobile? If I know how to disable the CameraController's mouseWheel event, I could resolve this...

In this case controller.coords acts as a getter and returns an instance of Point3D. To change x coordinate you have to set a new value for x in this instance and assign it back to "coords". I know, this isn't that convenient as simply setting x, y, z via separate properties, but this is how it's working right now.

OK, now its working

Thanks Mikhail. Here is the final OrbitCamera3D for anyone who wants to use it:

package {
	import flash.display.DisplayObject;
	import flash.events.MouseEvent;
	import alternativa.engine3d.controllers.WalkController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.display.View;
	import alternativa.types.Point3D;
	import alternativa.engine3d.core.Object3D;
	public class OrbitCamera3D extends Camera3D {
		public var viewCamera:Camera3D;
		public var controller:WalkController;
		public var onStartMoving:Function;
		public var onStopMoving:Function;
		public var onStartDragging:Function;
		public var onStopDragging:Function;
		private var eventsSourceObject:DisplayObject;
		public function OrbitCamera3D( eventsSourceObject:DisplayObject, view:View, distance:Number = 500 ) {
			super();
			viewCamera = new Camera3D();
			addChild( viewCamera );
			this.distance = distance;
			view.camera = viewCamera;
			this.eventsSourceObject = eventsSourceObject;
		};
		public function set distance( value:Number ):void {
			viewCamera.z = -value;
		};
		public function get distance():Number {
			return -viewCamera.z;
		};
		public function lookAt( point:Point3D = null ):void {
			controller.coords = point;
		};
		public function processInput():void {
			if( controller ) {
				controller.processInput();
			} else if( Camera3D(this).parent ) {
				buildController();
			};
		};
		public function set focalPointX( value:Number ):void { controller.coords = new Point3D(value, focalPointY, focalPointZ); };
		public function set focalPointY( value:Number ):void { controller.coords = new Point3D(focalPointX, value, focalPointZ); };
		public function set focalPointZ( value:Number ):void { controller.coords = new Point3D(focalPointX, focalPointY, value); };
		public function get focalPointX():Number { return controller.coords.x; };
		public function get focalPointY():Number { return controller.coords.y; };
		public function get focalPointZ():Number { return controller.coords.z; };
		private function buildController():void {
			controller = new WalkController( eventsSourceObject );
			controller.object = this;
			controller.unbindAll()
			controller.lookAt( new Point3D( 0, 0, 0 ) );
			controller.onStartMoving = function() {
				if( onStartMoving != null ) onStartMoving(); 
			};
			controller.onStopMoving = function() {
				if( onStopMoving != null ) onStopMoving(); 
			};
			eventsSourceObject.addEventListener( MouseEvent.MOUSE_DOWN, _onStartDragging );
			eventsSourceObject.addEventListener( MouseEvent.MOUSE_UP, _onStopDragging );
			addEventListener( MouseEvent.MOUSE_UP, _onStopDragging );
		};
		private function _onStartDragging( event:MouseEvent ):void {
			if( onStartDragging != null ) onStartDragging(); 
		};
		private function _onStopDragging( event:MouseEvent ):void {
			if( onStopDragging != null ) onStopDragging(); 
		};
	};
};

What if we add

to the buildController() method and also add

to enable mouse wheel zooming?