Неверное отображение объектов

Создаю последовательно куб и сферу, но сфера рисуется над кубом, даже тогда, когда он должен ее закрыть. Кто подскажет, как исправить проблему?

Информации не досдаточно, хотябы необходимо прикрепить код

This message was edited 1 time. Last update was at 18/12/2011 07:28:44

Куб переделал в шар, но проблема осталась ( и должна была) )

package {
	
	import alternativa.engine3d.controllers.SimpleObjectController;
	import alternativa.engine3d.core.Camera3D;
	import alternativa.engine3d.core.Object3DContainer;
	import alternativa.engine3d.core.View;
	import alternativa.engine3d.materials.FillMaterial;
	import alternativa.engine3d.materials.TextureMaterial;
	import alternativa.engine3d.objects.SkyBox;
	import alternativa.engine3d.primitives.Box;
	import alternativa.engine3d.primitives.GeoSphere;
	import alternativa.engine3d.primitives.Sphere;
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.TimerEvent;
	import flash.geom.Vector3D;
	import flash.utils.Timer;
	
	import mx.core.BitmapAsset;

public class Pegasus extends Sprite {
		
		[Embed(source="1.jpg")] private var t1:Class;
		[Embed(source="2.jpg")] private var t2:Class;
		[Embed(source="3.jpg")] private var t3:Class;
		[Embed(source="4.jpg")] private var t4:Class;
		[Embed(source="0.jpg")] private var t5:Class;
		[Embed(source="sun.jpg")] private var tsun:Class;
		
		private var rootContainer:Object3DContainer = new Object3DContainer();
		
		private var camera:Camera3D;
		
		private var sun:Sphere;
		
		private var sph:GeoSphere;
		
		private var con:SimpleObjectController;
		
		private var angle:Number = 0;
		
		private var timer:Timer;
		
		private var skybox:SkyBox;
		
		public function Pegasus() {
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;

camera = new Camera3D();
			camera.view = new View(stage.stageWidth, stage.stageHeight);
			addChild(camera.view);
			addChild(camera.diagram);
			
			camera.rotationX = -120*Math.PI/180;
			camera.y = -800;
			camera.z = 400;
			rootContainer.addChild(camera);
			
			var t_1:BitmapAsset = new t1;
			var texture1:TextureMaterial = new TextureMaterial(t_1.bitmapData);
			var t_2:BitmapAsset = new t2;
			var texture2:TextureMaterial = new TextureMaterial(t_2.bitmapData);
			var t_3:BitmapAsset = new t3;
			var texture3:TextureMaterial = new TextureMaterial(t_3.bitmapData);
			var t_4:BitmapAsset = new t4;
			var texture4:TextureMaterial = new TextureMaterial(t_4.bitmapData);
			var t_5:BitmapAsset = new t5;
			var texture5:TextureMaterial = new TextureMaterial(t_5.bitmapData);
			var t_sun:BitmapAsset = new tsun;
			var sunt:TextureMaterial = new TextureMaterial(t_sun.bitmapData);
			
			skybox = new SkyBox(100000,texture1,texture2,texture3,texture4,texture5,texture5,0.01);
			rootContainer.addChild(skybox);
			
			var material:FillMaterial = new FillMaterial(0xFF7700, 1, 1);
			
			sun = new Sphere(500, 100);
			sun.setMaterialToAllFaces(sunt);
			rootContainer.addChild(sun);
			
			sph = new GeoSphere(50,10,true);
			sph.setMaterialToAllFaces(material);
			sph.x = 700; 
			sph.y = 700;
			rootContainer.addChild(sph);
					
			timer = new Timer(40,0);
			timer.addEventListener(TimerEvent.TIMER, tmr);
			timer.start();
			
			con = new SimpleObjectController(stage,camera,200);
			
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
			
		}
		
		private function onEnterFrame(e:Event):void {
			camera.view.width = stage.stageWidth;
			camera.view.height = stage.stageHeight;

sun.rotationZ -= 0.01;
						
			con.update();
			camera.render();
		}
		
		private function tmr(e:TimerEvent):void {
			sph.x = Math.round(700*Math.cos(angle));
			sph.y = Math.round(700*Math.sin(angle));
			angle = angle+Math.PI/1800;
			
			// Вращение сферы вокруг солнца
		}
		
	}
}

Object3DContainer это контейнер без сортировки.
http://wiki.alternativaplatform.com/Контейнер

Попробуйте ConflictContainer или DistanceSortContainer.

Спасибо, помогло!